#!/usr/bin/perl
# full path of Perl after "#!".

# Copyright (C) 2004 Infotechnica Corporation, All rights reserved.

use strict;
use lib '.';
use CGI::Carp qw(fatalsToBrowser);

# jcode.pl required.
require 'jcode.pl';

# httmpl.pl required.
require 'httmpl.pl';

# --- define ---
# Configuration file name
my $config_file = 'config_h.txt';

# Key name
my %form_key = (
	id     => 'id',
	query1 => 'q1',
	query2 => 'q2',
	query3 => 'q3',
	query4 => 'q4',
	query5 => 'q5',
	query6 => 'q6',
	query7 => 'q7',
	query8 => 'q8',
	query9 => 'q9',
	school => 'qs',
	page   => 'page',
);

my %form_value = (
	id     => '',
	query1 => '',
	query2 => '',
	query3 => '',
	query4 => '',
	query5 => '',
	query6 => '',
	query7 => '',
	query8 => '',
	query9 => '',
	school => '',
	page   => '',
	ERROR  => '',
);

my %Didx = (
	id          =>  0,
	zone        =>  1,
	s_layout    =>  2,
	s_price     =>  3,
	el_school   =>  4,
	type        =>  5,
	address1    =>  6,
	address2    =>  7,
	layout      =>  8,
	price       =>  9,
	land_area   => 10,
	land_tsubo  => 11,
	bldg_area   => 12,
	bldg_tsubo  => 13,
	frame       => 14,
	aspect      => 15,
	parking     => 16,
	elapsed     => 17,
	purpose     => 18,
	ratio       => 19,
	drainage    => 20,
	gas         => 21,
	jh_school   => 22,
	remarks     => 23,
	transaction => 24,
	agency      => 25,
	regdate     => 26,
	image1      => 27,
	image2      => 28,
);

# Template file name
my $template_file = '';

# CSV-file path
my $CSVFilePath = '';

# Kanji code for display
my $disp_code = 'sjis';
my $html_charset = 'Shift_JIS';

# Max selection
my $MaxSelection = 1;

# Max rows per page
my $MaxRow = 10;

# term of What's new (day)
my $WhatsnewTerm = 30;

# Tag
my %tags = (
	ERROR        => '<!--## ERROR ##-->',
);

# --- main ---
$| = 1;
# get configure
my $configure = &GetConfigure($config_file);
$MaxRow = $configure->{PAGE_LIMMIT} if $configure->{PAGE_LIMMIT};
$MaxSelection = $configure->{MAX_SELECTION} if $configure->{MAX_SELECTION};
$WhatsnewTerm = $configure->{WHATSNEW_DAY} if $configure->{WHATSNEW_DAY};
$template_file = $configure->{SYSTEM_TEMPLATE_SEARCH} if $configure->{SYSTEM_TEMPLATE_SEARCH};
$CSVFilePath = $configure->{SYSTEM_CSV_FILE_PATH} if $configure->{SYSTEM_CSV_FILE_PATH};

my $query_string;
if ($ENV{'REQUEST_METHOD'} eq 'GET') {
	$query_string = $ENV{'QUERY_STRING'};
} elsif ($ENV{'REQUEST_METHOD'} eq 'POST') {
	read(STDIN, $query_string, $ENV{'CONTENT_LENGTH'});
} else {
	&error("Request method is NOT 'GET' or 'POST'.");
}
if ($query_string) {
	my @elements = split(/&/, $query_string);
	my $element;
	foreach ( keys %form_key ) {
		&jcode::convert(\$form_key{$_}, 'euc') if ($form_key{$_});
	}
	foreach $element ( @elements ) {
		my($idx, $buf) = split(/=/, $element);
		$idx =~ tr/+/ /;
		$idx =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("H2", $1)/eg;
		&jcode::convert(\$idx, 'euc') if ($idx);
		$buf =~ tr/+/ /;
		$buf =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("H2", $1)/eg;
		&jcode::convert(\$buf, 'euc') if ($buf);
		foreach ( keys %form_key ) {
			if ($idx eq $form_key{$_}) {
				my $temp_val = $buf;
				if ($temp_val) {
					&jcode::tr(\$temp_val, 
						"\xa3\xb0-\xa3\xb9\x8e\xb0\xa1\xbc\xa1\xbd\xa1\xbe\xa1\xdd", 
						'0-9--------', '');
					$temp_val =~ s/[^0-9A-Za-z_-]//g;
					$form_value{$_} = $temp_val;
				}
			}
		}
	}
}

# get current time
my $currentUTC = time;

# page num
my $PageNum = 1;
$PageNum = $form_value{'page'} if ($form_value{'page'});

# get table data
my $TableData = &GetTableData($config_file);
my @tbl_query = ();

# search
my ($Results, $Results_num) = &searchData();

# show page
my $lists = {};
$lists->{CHAR_SET} = $html_charset;

$lists->{RESULT_NUM} = $Results_num;
$lists->{EXIST_RESULT} = ($Results_num > 0);

my $qidx = 0;
foreach $qidx ( 1 .. $MaxSelection ) {
	$lists->{'QUERY' . $qidx} = $form_value{'query' . $qidx} 
									if ($form_value{'query' . $qidx});
	# option
	$tbl_query[$qidx] = &makeTable($TableData, 'TBL_Q' . $qidx);
	my $tmp_html = '';
	my $no_cond = '(No condition)';
	$no_cond = $configure->{JP_OPT_NO_CONDITION} if $configure->{JP_OPT_NO_CONDITION};
	$tmp_html .= "<option value=\"\">" . $no_cond . "<\/option>\n";
	foreach ( 0 .. $#{ $tbl_query[$qidx]->{CODE} } ) {
		my $selected = '';
		if ($tbl_query[$qidx]->{CODE}[$_] eq $form_value{'query' . $qidx}) {
			$selected = ' selected';
		}
		$tmp_html .= "<option value=\"" . $tbl_query[$qidx]->{CODE}[$_] . "\"$selected>";
		$tmp_html .= $tbl_query[$qidx]->{NAME}[$_] . "<\/option>\n";
	}
	$lists->{'OPTIONS_QUERY' . $qidx} = $tmp_html;
}

$lists->{SCHOOL} = $form_value{school} if ($form_value{school});
my $tbl_school = &makeTable($TableData, 'TBL_SCHOOL');
# zone is setted
if ($form_value{query1} ne '') {
	my $tmp_html = '';
	my $no_cond = '(No condition)';
	$no_cond = $configure->{JP_OPT_NO_CONDITION} if $configure->{JP_OPT_NO_CONDITION};
	$tmp_html .= "<option value=\"\">" . $no_cond . "<\/option>\n";
	my @schools = sort { $tbl_school->{KANA}->[$a] cmp $tbl_school->{KANA}->[$b] } 
					grep( ($tbl_school->{ZONE}->[$_] eq $form_value{query1}), 
							( 0 .. $#{ $tbl_school->{CODE} } ) );
	foreach ( @schools ) {
		my $selected = '';
		if ($tbl_school->{CODE}[$_] eq $form_value{school}) {
			$selected = ' selected';
		}
		$tmp_html .= "<option value=\"" . $tbl_school->{CODE}[$_] . "\"$selected>";
		$tmp_html .= $tbl_school->{NAME}[$_] . "<\/option>\n";
	}
	$lists->{OPTIONS_SCHOOL} = $tmp_html;
} else {
	my $sel_zone = '(Select ZONE)';
	$sel_zone = $configure->{JP_OPT_SELECT_ZONE} if $configure->{JP_OPT_SELECT_ZONE};
	$lists->{OPTIONS_SCHOOL} = "<option value=\"\">" . $sel_zone . "<\/option>\n";
}

# page control
my $MaxPage = int($Results_num / $MaxRow);
if (($MaxPage * $MaxRow) != $Results_num) {
	$MaxPage++;
}
if ($PageNum < 1) {
	$PageNum = 1;
} elsif ($PageNum > $MaxPage) {
	$PageNum = $MaxPage;
}
$lists->{CURRENT_PAGE} = $PageNum;
$lists->{MAX_PAGE} = $MaxPage;
if ($PageNum == 1) {
	$lists->{PREV_PAGE} = 1;
} else {
	$lists->{PREV_PAGE} = $PageNum - 1;
}
if ($PageNum == $MaxPage) {
	$lists->{NEXT_PAGE} = $MaxPage;
} else {
	$lists->{NEXT_PAGE} = $PageNum + 1;
}
my @pgtemp;
foreach ( 1 .. $MaxPage ) {
	$pgtemp[$_ - 1]->{PAGE} = $_;
}
$lists->{PAGE_TAG} = \@pgtemp;

# sort
my $st = $MaxRow * ($PageNum - 1);
my $ed = $MaxRow * $PageNum - 1;
if ($PageNum == $MaxPage) {
	$ed = $Results_num - 1;
}
$Results = [ (sort({ $b->[$Didx{regdate}] cmp $a->[$Didx{regdate}] } @$Results))[$st .. $ed] ];

$lists->{LOOP_RESULTS} = &makeList();

# add Configure
my $mkey;
foreach $mkey (keys %$configure) {
	$lists->{$mkey} = $configure->{$mkey};
}

my ($tree, @errors);
if (open(TMPL, $template_file)) {
	my @template_lines = <TMPL>;
	close(TMPL);
	my $tmplline;
	foreach $tmplline ( @template_lines ) {
		&jcode::convert(\$tmplline, 'euc');
	}
	($tree, @errors) = &httmpl::Parse(@template_lines);
	unless ($tree) {
		my $msg = join "<br>", @errors;
		&error($msg);
	}
} else {
	&error('Could not open template file.');
}

my $content = &httmpl::Traverse($tree, $lists);
&jcode::convert(\$content, $disp_code);
my $cont_len = length($content);

# compact policy for IE6
#print "P3P: CP=\"NOI TAIa OUR\"\n";

print << "HTTPHEADER";
Cache-Control: no-cache, no-store, must-revalidate
Cache-Control: private
Pragma: no-cache
Expires: 0
Content-Length: $cont_len
Content-Type: text/html; charset=$html_charset

HTTPHEADER

print $content;

exit;
# ^^^ main ^^^

# --- error ---
sub error {
	my ($msg) = @_;
	$msg =~ tr/+;}{][|\*^%$#!`//d;
	$msg =~ s/&/&amp;/g;
	$msg =~ s/</&lt;/g;
	$msg =~ s/>/&gt;/g;
	$msg =~ s/\'/&#39;/g;
	$msg =~ s/\(/&#40;/g;
	$msg =~ s/\)/&#41;/g;
	$msg =~ s/\"/&quot;/g;
	$form_value{'ERROR'} = $msg;
	&showPage('error.html');
	exit 0;
}

sub showPage {
	my ($html_file_name) = @_;
	if ($html_file_name =~ /^https?\:/) {
		print "Location: $html_file_name\n";
		print "Content-type: text/html\n\n";
		print "<html><head><title>Jump</title>\n";
		print "<meta http-equiv=\"Refresh\" target=\"_self\" content=\"1;URL=$html_file_name\">\n";
		print "</head><body onload=setTimeout(\"location.href='$html_file_name'\",1000)>\n";
		print "<a href=\"$html_file_name\">Click here to next.</a></body></html>\n";
	} else {
		my $content = &getHTML($html_file_name);
		&jcode::convert(\$content, $disp_code);
		my $cont_len = length($content);
		print "Cache-Control: no-cache, no-store, must-revalidate\n";
		print "Cache-Control: private\n";
		print "Pragma: no-cache\n";
		print "Expires: 0\n";
		print "Content-Type: text/html\n";
		print "Content-Length: $cont_len\n\n";
		print $content;
	}
}

sub getHTML {
	my ($html_file) = @_;
	unless (open(HTMLF, $html_file)) {
		print "Content-type: text/html\n\n";
		print "<html><head><title>Error</title>\n";
		print "</head><body><center>\n";
		print "<h2>Error: Could not open html-file.</h2>\n";
		print "<br>Could not open $html_file.<br>\n";
		print "<hr width=\"75\%\"></center></body></html>\n";
		exit 0;
	}
#	local($/) = undef;
	my $html_lines = '';
	my $temp_lines = '';
	my $temp_line;
	while (defined($temp_line = <HTMLF>)) {
		$temp_lines .= $temp_line;
		&jcode::convert(\$temp_line, 'euc');
		foreach ( keys %tags ) {
			$temp_line =~ s/$tags{$_}/$form_value{$_}/g;
		}
		$html_lines .= $temp_line;
	}
	close(HTMLF);
	$disp_code = &jcode::getcode(\$temp_lines);
	$temp_lines = undef;
	return $html_lines;
}
# ^^^ error ^^^

# --- sanitize ---
sub sanitize {
	my $input = shift;
	$input =~ tr/+;}{][|\*^$#!`//d;
#	$input =~ tr/:%//d;
	$input =~ s/&/&amp;/g;
	$input =~ s/</&lt;/g;
	$input =~ s/>/&gt;/g;
	$input =~ s/"/&quot;/g;
	$input =~ s/'/&#39;/g;
	$input =~ s/\(/&#40;/g;
	$input =~ s/\)/&#41;/g;
	return $input;
}

sub formatNumber {
	my $n = shift;
	if ($n =~ /^[-+]?\d\d\d\d+/g) {
		my ($l, $m);
		for ($l = pos($n) - 3, $m = $n =~ /^[-+]/; $l > $m; $l -= 3) {
			substr($n, $l, 0) = ',';
		}
	}
	return $n;
}
# ^^^ sanitize ^^^

# --- read file ---
sub GetConfigure {
	my($template_file) = @_;
	unless (open(TMPL, $template_file)) {
		print "Content-type: text/html\n\n";
		print "<html><head><title>Error</title>\n";
		print "</head><body><center>\n";
		print "<h2>Error: Could not open config-file.</h2>\n";
		print "<br>Could not open $template_file : $! .<br>\n";
		print "<hr width=\"75\%\"></center></body></html>\n";
		exit 0;
	}
	local($/) = undef;
	my @conf_template = <TMPL>;
	close(TMPL);
	my $macros;
	my $rexp_macro = '<\!--##define ([A-Za-z]\w*)=[\'\"](.+)[\'\"]-->';
	my $temp_line;
	foreach $temp_line ( @conf_template ) {
		&jcode::convert(\$temp_line, 'euc');
		$temp_line =~ s/$rexp_macro/
						$macros->{$1} = $2;
						'';
						/ge;
	}
	undef @conf_template;
	undef $temp_line;
	return $macros;
}

sub GetTableData {
	my($template_file) = @_;
	unless (open(TMPL, $template_file)) {
		print "Content-type: text/html\n\n";
		print "<html><head><title>Error</title>\n";
		print "</head><body><center>\n";
		print "<h2>Error: Could not open config-file.</h2>\n";
		print "<br>Could not open $template_file : $! .<br>\n";
		print "<hr width=\"75\%\"></center></body></html>\n";
		exit 0;
	}
	local($/) = undef;
	my @conf_template = <TMPL>;
	close(TMPL);
	my $tables;
	my $rexp_table = '<\!--##table ([A-Za-z]\w*)=[\'\"](.+)[\'\"]-->';
	my $temp_line;
	foreach $temp_line ( @conf_template ) {
		&jcode::convert(\$temp_line, 'euc');
		$temp_line =~ s/$rexp_table/
						push @{ $tables->{$1} }, ( $2 );
						'';
						/ge;
	}
	undef @conf_template;
	undef $temp_line;
	return $tables;
}

sub makeTable {
	my ($tables, $table_key) = @_;
	my $table = {};
	my @field_names = split "\t", shift @{ $tables->{$table_key} };
	foreach ( @{ $tables->{$table_key} } ) {
		my @fields = split "\t", $_;
		foreach (0..$#field_names) {
			push @{ $table->{$field_names[$_]} }, $fields[$_];
		}
	}
	return wantarray ? ($table, \@field_names) : $table;
}
# ^^^ read file ^^^

# --- date time ---
sub dateNow {
	my ($sec, $min, $hour, $mday, $mon, $year, $wday) = localtime($currentUTC);
	$year += 1900;
	$mon++;
	return sprintf("%04d%02d%02d", $year, $mon, $mday);
}

sub getPastDays {
	my $date = shift;	# YYYYMMDD
	# date to days from 2000/01/01
	my $days = 0;
	if ($date =~ /^(\d{4})(\d{2})(\d{2})$/) {
		my ($year, $month, $mday) = ($1, $2, $3);
		if ($year > 2000) {
			$days = ($year - 2000) * 365;
			my $y = 0;
			for ($y = 2000; $y < $year; $y++) {
				$days += ($y % 4 == 0 and ($y % 400 == 0 or $y % 100 != 0));
			}
			$days += (0, 31, 59, 90, 120, 151, 181, 212, 243, 273, 304, 334)[$month - 1];
			$days += ($month > 2 and 
						($year % 4 == 0 and ($year % 400 == 0 or $year % 100 != 0)));
			$days += $mday - 1;
		}
	}
	return $days;
}
# ^^^ date time ^^^

# --- make data ---
sub searchData {
	my $data = [];
	my $hit_num = 0;
	unless (open(CSV, '<' . $CSVFilePath)) {
		&error("Could not open file.($CSVFilePath) : $!");
	}
	eval { flock(CSV, 1); };	# lock
	my $tmp_line = '';
	while (defined($tmp_line = <CSV>)) {
		$tmp_line .= <CSV> while ($tmp_line =~ tr/"// % 2 and !eof(CSV));
		&jcode::convert(\$tmp_line, 'euc');
		$tmp_line =~ s/(?:\x0D\x0A|[\x0D\x0A])?$/,/;
		my @line_values = map {/^"(.*)"$/s ? scalar($_ = $1, s/""/"/g, $_) : $_}
					($tmp_line =~ /("[^"]*(?:""[^"]*)*"|[^,]*),/g);
		my $hit = 1;
		foreach ( 1 .. $MaxSelection ) {
			if ($form_value{'query' . $_} 
				and $form_value{'query' . $_} ne $line_values[$_]) {
				$hit = 0;
			}
		}
		if ($hit and $form_value{school} 
			and $form_value{school} ne $line_values[$Didx{el_school}]) {
			$hit = 0;
		}
		if ($hit) {
			$data->[$hit_num] = \@line_values;
			$hit_num++;
		}
	}
	close(CSV);
	return wantarray ? ($data, $hit_num) : $data;
}

sub makeList {
	my @list;
	my $i = 0;
	my $now = &getPastDays(&dateNow());
	my $arr_ref = [];
	foreach $arr_ref ( @$Results ) {
		$list[$i]->{ID} = &sanitize($arr_ref->[$Didx{id}]);
		foreach ( 0 .. $#{ $tbl_query[$Didx{zone}]->{CODE} } ) {
			if ($tbl_query[$Didx{zone}]->{CODE}[$_] eq $arr_ref->[$Didx{zone}]) {
				$list[$i]->{zone} = &sanitize($tbl_query[$Didx{zone}]->{NAME}[$_]);
			}
		}
		foreach ( 0 .. $#{ $tbl_school->{CODE} } ) {
			if ($tbl_school->{CODE}[$_] eq $arr_ref->[$Didx{el_school}]) {
				$list[$i]->{el_school} = &sanitize($tbl_school->{NAME}[$_]);
			}
		}
		$list[$i]->{type}       =     &sanitize($arr_ref->[$Didx{type}]);
		$list[$i]->{address1}   =     &sanitize($arr_ref->[$Didx{address1}]);
		$list[$i]->{layout}     =     &sanitize($arr_ref->[$Didx{layout}]);
		$list[$i]->{price}      = &formatNumber($arr_ref->[$Didx{price}]);
		$list[$i]->{land_tsubo} =     &sanitize($arr_ref->[$Didx{land_tsubo}]);
		$list[$i]->{bldg_tsubo} =     &sanitize($arr_ref->[$Didx{bldg_tsubo}]);
		if ($now - &getPastDays($arr_ref->[$Didx{regdate}]) > $WhatsnewTerm) {
			$list[$i]->{NEW} = (0);
		} else {
			$list[$i]->{NEW} = (1);
		}
		$i++;
	}
	return \@list;
}
# ^^^ make data ^^^